alias snow {
  if $1 isnum 1- {
    ;; Initializing the window.
    window -apdk @snow
    var %i = 1, %w = $window(@snow).w, %h = $window(@snow).h, %m = $1
    ;; Making sure it's black.
    drawrect -fr @snow 0 1 0 0 %w %h
    ;; Drawing every of the <n> snowballs. \o/
    while %i <= %m {
      set %snow $+ %i $r(1,%w) $r(1,%h)
      drawdot -r @snow 16777215 2 $($+(%,snow,%i),2)
      .timersnow $+ %i -m 0 2 _snow %i %w %h
      inc %i
    }
  }
  elseif $1 = off {
    unset %snow*
    .timersnow* off
  }
}
alias -l _snow {
  ;; This is the local alias to move the snowball.
  if !$window(@snow) { snow off | return }
  ;; Some faster, some slower.
  if $r(0,3) {
    var %xy = $($+(%,snow,$1),2), %x = $gettok(%xy,1,32), %y = $gettok(%xy,2,32)
    ;; To the top, if on the ground.
    if %y > $3 { %y = 0 }
    if %x < 0 || %x > $2 { %x = $r(1,$2) }
    ;; "Removing" its old position, ...
    drawdot -r @snow 0 2 %xy
    ;; moving it to the left, or to the right...
    if $r(0,2) { inc %x $iif($r(0,1),-) $+ $r(1,3) }
    ;; to the ground...
    inc %y $r(1,$r(1,4))
    ;; and finally drawing.
    drawdot -r @snow 16777215 2 %x %y
    set % $+ snow $+ $1 %x %y
  }
}
menu @snow {
  abort:snow off
}