;;Coded By SaW (Nebiliymben)
;;07 Temmuz 2008
;;Kaynak belirtilmeden kullanılmaması rica olunur.
;;iletişim: 
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.



; dll'i tanıtıyoruz. (mdx aliasına atıyoruz.)
alias mdx return $dll(mdx.dll,$1,$2-)
;Animasyonu yapan kısım.
alias animac {
  var %i 0, %t 0, %s $rand(1,3)
  ; En sabit yukarı ve aşağı doğru animasyon
  if %s == 1 {
    while (%i <= $1 || %t <= $2) {
      dialog -srb $3 -1 -1 %i $2
      if (%t < $2) inc %t
      if (%i < $1) inc %i
    }
  }
  ; Boy sabit sağa ve sola doğru animasyon
  if %s == 2 {
    while (%i <= $1 || %t <= $2) {
      dialog -srb $3 -1 -1 $1 %t
      if (%t < $2) inc %t
      if (%i < $1) inc %i
    }
  }
  ; merkezden kenarlara doğru animasyon
  if %s == 3 {
    while (%i <= $1 || %t <= $2) {
      dialog -srb $3 -1 -1 %i %t
      if (%t < $2) inc %t
      if (%i < $1) inc %i
    }
  }
}

; Burada Dialogları Hem renklendiriyoruz, hemde animasyon komutunu burada veriyoruz
on *:DIALOG:*:init:*:{
  ; Bir dialog açıldığında o d dialogun enini, boyunu ve adını değişkene atıyoruz
  var %v = $calc($dialog($dname).w * 82 / 166) $calc($dialog($dname).h * 60 / 134) $dname
  mdx SetMircVersion $version 
  mdx MarkDialog $dname 
  ; Dialogun arka plan rengini belirliyoruz. Buradan renkte değişiklik yapabilirsiniz
  mdx SetDialog $dname bgcolor $rgb(74,112,139)
  var %~ = 1
  ; Bu %j değişkeni bir dialogun içindeki id sayısıdır, genelde daha az olur 
  ; ama büyük dialoglarda bu ve bundan daha fazlası da olabilir, ancak 
  ; açılışta hem döngünün çok uzun sürüp yavaşlamaması hem de mümkün 
  ; olduğunca eksik id kalmaması için 700 sayısını seçtim, eğer sizin 
  ; scriptinizde daha fazla id'li dialog varsa artırın, eğer hep daha az id'ler varsa azaltabilirsiniz.
  var %j = 700
  var %s = 0
  ; Bütün 1'den 700'e kadar tüm id'ler için aşağıdaki komutları uygulatıyoruz.
  while %~ <= %j {
  ; Bu if'in açılmasının nedeni, dialogun içindeki bazı edit ve box kısımlarını  
  ; (değer girilebilen) mdx'in değiştirmemesi ve o kutucuk ve yazıların belirgin kalabilmesi..
    if ($did(%~).isid == $true) {
  ; Bu if ise, "eğer %~ değişkeninin ifade ettiği id değeri var ise" manasına gelmektedir.
      if ($did($dname,%~)) {
        ; Dialog içindeki yazı arka plan rengidir.. Dilerseniz değiştirebilirsiniz.
        mdx SetColor $dname %~ textbg $rgb(108,166,205)
        ; Dialog içindeki yazı rengidir.. Dilerseniz değiştirebilirsiniz.
        mdx SetColor $dname %~ text $rgb(232,232,232)
        ; Dialog içindeki genel arka plan rengidir.. Dilerseniz değiştirebilirsiniz.
        mdx SetColor $dname %~ background $rgb(108,166,205)
        ; Genel yazı fontu ve ayarlarıdır.. Dilerseniz değiştirebilirsiniz.
        mdx SetFont $dname %~ Turkish 14 200 arial       
      }
      inc %s
    }
    inc %~
  }
  ; dialog açıldığında 1 milisaniye sonra animasyona başlatır.
  .timer -m 1 1 animac %v
}

 on *:DIALOG:*:init:*:{

Yazan yeri

on *:DIALOG:Senin_Dialogunun_Adı:init:*:{

Kısmını değiştirmen yeterli olacaktır..

Eğer Bütün dialoglara değil de birden çok dialoga uygulamak isterseniz:

on *:DIALOG:*:init:*:{
if ($dname == Dialogbir || $dname == Dialogiki || $dname == Dialogüç) {

gibi bir if satırı açarak sadece üç ayrı dialoga (sayı istediğiniz kadar artırılabilir) uygulatabilirsiniz..

Yine aynı mantıkla hareket ederek; bütün dialoglara uygulasın ama sadece bir ya da bir kaçına uyglumasını istemiyorsanız:

on *:DIALOG:*:init:*:{
if ($dname == Dialogbir || $dname == Dialogiki || $dname == Dialogüç) { halt }

Şeklinde yaparsanız bu belirleyeceğiniz dialog ya da dilaoglara uygulamayacaktır.

alias mdx return $dll($findfile($mircdir,mdx.dll,1),$1,$2-)