IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - Admin Listesi (https://www.ircforumlari.net/mirc-scripting-sorunlari/935119-admin-listesi.html)

Merhabalar kullandığım bir kod mIRCim ile beraber silindi kod konusunda yardımcı olabilirmisiniz mümkünse, forumda benzer kod aradım fakat bulamadım, ufak bir koddu 243 raw numarası ile yapılmıştı yanılmıyorsam stats-o listesini istediğimiz kanallara 100 seviye & ekliyordu tüm listedeki herkesi , bir kaç muaf nick haricinde kullanımı !adminekle #kanaladı gibi

Cevap: Admin Listesi

Alıntı:

Melek Nickli Üyeden Alıntı (Mesaj 1042531982)

Kod:



raw *:* {

  haltdef

  if $numeric == 243 && %ekle? && !$findtok(%muaf_list,$5,32) {

    var %say = 1

    while (%say <= $gettok(%ekle?,0,32)) {

      msg %kanal? $+($5,$chr(44))  $+ $gettok(%ekle?,%say,32) kanalına eklendi.

      chanserv access $gettok(%ekle?,%say,32) add $5 100

      inc %say

    }

  }

  elseif $numeric == 219 { msg %kanal? İşlem tamamlanmıştır. | unset %kanal? }

}

on *:text:!access*:#kanal: {

  if !$istok(ekle muaf,$2,32) { msg # !access ekle #kanal1 kanal2 #kanal3 - !access muaf nick olarak kullaniniz. | return }

  elseif $2 == ekle {

    if !$3 { msg # Lütfen kanalları belirtin. [Çoklu kanal için, boşluk bırakınız. Örn: !access ekle #kanal #kanal2 #kanal3] | return } 

    else {

      set -u5 %ekle? $3- | set %kanal? $chan | stats o

    }

  }

  elseif $2 == muaf {

    if !$3 { msg # Lütfen nick belirtin. | return } 

    elseif $3 == liste {

      var %say = 1

      while (%say <= $gettok(%muaf_list,0,32)) {

        msg $chan Muaf:  $+ $gettok(%muaf_list,%say,32)

        inc %say

      }

    }

    else {

      if $findtok(%muaf_list,$3,32) {

        set %muaf_list $remtok(%muaf_list,$3,32) | msg # $3 Nick'i başarıyla muaf listesinden silinmiştir.

      }

      else {

        set %muaf_list $addtok(%muaf_list,$3,32) | msg # $3 Nick'i başarıyla muaf olarak eklenmiştir.

      }

    }

  }

}

!access ekle #kanal1 #kanal2 #kanal3 [100 Seviyeden access ekler.]
!access muaf liste
!access muaf nick [Nick muafsa muaftan siler, değilse muaf ekler.]

Değiştirilecek yerler:

Kod:

Değiştir (13. Satır) --> on *:text:!access*:#kanal: {

Cevap: Admin Listesi

Kod:



/*

 Kullanım [Local-Sadece kendin uygulayabilirsin.];

        !access ekle #kanal1 #kanal2 #kanal3 [100 Seviyeden access ekler.]

        !access muaf liste

        !access muaf nick [Nick muafsa muaftan siler, değilse muaf ekler.]

*/

raw *:* {

  if $numeric == 243 && %ekle? && !$findtok(%muaf_list,$5,32) {

    haltdef

    var %say = 1

    while (%say <= $gettok(%ekle?,0,32)) {

      echo 3 -ta * $+($5,$chr(44))  $+ $gettok(%ekle?,%say,32) kanalına eklendi.

      chanserv access $gettok(%ekle?,%say,32) add $5 100

      inc %say

    }

  }

  elseif $numeric == 219 && %ekle? {

    haltdef

    echo 2 -ta * İşlem tamamlanmıştır.

  }

}

on *:input:*: {

  if !access* iswm $1 {

    haltdef

    if !$istok(ekle muaf,$2,32) { echo 2 -ta * !access ekle #kanal1 kanal2 #kanal3 - !access muaf nick olarak kullaniniz. | return }

    elseif $2 == ekle {

      if !$3 { echo 2 -ta * Lütfen kanalları belirtin. [Çoklu kanal için, boşluk bırakınız. Örn: !access ekle #kanal #kanal2 #kanal3] | return } 

      else {

        set -u5 %ekle? $3- | echo 2 -ta * Bekleyiniz.. |  stats o

      }

    }

    elseif $2 == muaf {

      if !$3 { echo 2 -ta * Lütfen nick belirtin. | return } 

      elseif $3 == liste {

        if !%muaf_list { echo 4 -ta * Hiç muaf yok. | return }

        var %say = 1

        while (%say <= $gettok(%muaf_list,0,32)) {

          echo 2 -ta * Muaf:  $+ $gettok(%muaf_list,%say,32)

          inc %say

        }

      }

      else {

        if $findtok(%muaf_list,$3,32) {

          set %muaf_list $remtok(%muaf_list,$3,32) | echo 2 -ta * $3 Nick'i başarıyla muaf listesinden silinmiştir.

        }

        else {

          set %muaf_list $addtok(%muaf_list,$3,32) | echo 2 -ta * $3 Nick'i başarıyla muaf olarak eklenmiştir.

        }

      }

    }

  }

}

Diğeri bot içindi. Bu da input olarak, kusura bakma sonradan fark ettim.

Cevap: Admin Listesi

Çok teşekkür ederim istediğim kod buydu harikasınız