Tekrar Korumasında bir Sorun!.. - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Cappystarjoe · 29 Ağustos 2005, 12:12

alias sequuummm {
if %KanalaTekrar == kick { .kick $chan $nick $tipz(Tekrar Koruması -!- Lütfen Tekrar Etmeyiniz!..) %Iconi }
if %KanalaTekrar == Sureli { .ban -ku $+ %KanalaTekrar.sure $chan $nick 2 $tipz(Tekrar Koruması -!-2 %KanalaTekrar.max.sure 4sn. içinde2 %KanalaTekrar.max.mesaj 4 adetten fazla 2(Text/Notice/Action)4 iletildi -!-2 %KanalaTekrar.sure 4sn. Banlandınız!!!) %Iconi }
if %KanalaTekrar == kickban { .ban -k $chan $nick 2 $tipz(Tekrar Koruması -!-2 %KanalaTekrar.max.sure 4sn. içinde2 %KanalaTekrar.max.mesaj 4 adetten fazla 2(Text/Notice/Action)4 iletildi -!- Banlandınız!!!) %Iconi }
.echo -s $timestamp 4***2 $nick 1 $+ $chan 4kanalında Tekrar yaptığı için $ktkrr | .linesep -s
}
alias ktkrr {
if %KanalaTekrar == kickban { .return kanaldan banlandı!.. %Iconi }
if %KanalaTekrar == Sureli { .return kanaldan2 %KanalaTekrar.sure 4saniye uzaklaştırıldı!.. %Iconi }
if %KanalaTekrar == kick { .return kanaldan atıldı!.. %Iconi }
}
on @*:text:*:#:{
.inc -u [ $+ [ %KanalaTekrar.max.sure ] ] %Kanalatekrar.text. [ $+ [ $nick ] ] [ $+ [ $1- ] ] 1
if (%KanalaTekrar.text. [ $+ [ $nick ] ] [ $+ [ $1- ] ] >= %KanalaTekrar.max.mesaj) {
.sequuummm
.unset %KanalaTekrar.text. [ $+ [ $nick ] ] [ $+ [ $1- ] ]
}
}

Şimdi bu kodda anlayamadığım birşey var bazen sorunsuz çalışıyor bazende;

* /inc: Geçersiz parametre

hatası veriyor. Bunun sebebi ne olabilir?

Ek bilgi olarakda variables da şu şekilde setlenmiş değerler olduğunu göz önüne alalım;
%KanalaTekrar kickban
%KanalaTekrar.max.sure 30
%KanalaTekrar.max.mesaj 3
%KanalaTekrar.sure 60

Alience · 29 Ağustos 2005, 12:31

on @*:text:*:#:{
.inc -u [ $+ [ %KanalaTekrar.max.sure ] ] %Kanalatekrar.text. [ $+ [ $nick ] ] [ $+ [ $1- ] ] 1
hatası burada ya [ $+ [ %KanalaTekrar.max.sure ] ] yada %Kanalatekrar.text. [ $+ [ $nick ] ] [ $+ [ $1- ] ] değerleri null olarak donuyor!

Cappystarjoe · 29 Ağustos 2005, 12:45

Hatanın o satırda olduğunu anladım zaten. Benim anlamadığım neden bazen null olarak dönmesi bazen de sorunsuz çalışması?

29 Ağustos 2005, 16:05

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


on *:TEXT:*:#: {
  if ($hget(flood,$nick)) hinc flood $nick
  else hadd $+(-u,$hget(flood,sure)) flood $nick 1 
 
  if $hget(flood,$nick) >= $hget(flood,flood) {
    ban $chan $nick 2
    kick $chan $nick Flood Yapmak Yasaktır
 
    hdel flood $nick
  }
}
 
on *:START: {
  if $findfile($mircdir,flood.data,1) { hmake flood | hload flood flood.data }
  else { hmake flood 5 | hsave flood flood.data }
}
 
alias flood { 
  if ($1 == sure) { 
    if ($2 isnum) { hadd flood sure $2 | echo -a Yeni Flood Süresi: $hget(flood,sure) | hsave flood flood.data }
  }
  elseif ($1 == izin) {
    if ($2 isnum) { hadd flood flood $2 | echo -a Yeni Flood İzniniz: $hget(flood,flood) | hsave flood flood.data }
  }
}

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

29 Ağustos 2005, 16:05

Burada 3 saniye 5 kez demiştim
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

ayarlar için

/flood sure <saniye>
/flood izin <izin verilen flood>

Cappystarjoe · 29 Ağustos 2005, 16:46

goXXip çok teşekkür ederim yazdığın kod için.

Fakat ben yukarıdaki kodun neden çalışmadığını anlamak istiyorum. Bu konuda birşeyler söyleyebilirsen memnun olurum.

Bu, tabii ki diğer arkadaşlar için de geçerli...

Sevgiler... Saygılar...

Alience · 29 Ağustos 2005, 17:10

[ $+ [ $1- ] ] yi yazmışsın oraya oda genellikle space character içerir ve inc fonksiyonuda doğal olarak onları yeni parametre zanedeceği için inc bu şekilde kullanılmaz diye uyarı verir. dikkat edersen selam, naber gibi tek kelime içerenlerde bir halt uyarı vermez selam nasılsın gibi boşluklularda verir.

MephisTo · 29 Ağustos 2005, 17:13

inc $+(-u,%KanalaTekrar.max.sure) ...

diye değiştir o satırı. [ kullanmana gerek yok ilk kısımda.

Cappystarjoe · 29 Ağustos 2005, 17:41

DMS haklısın...

sorunu anladım. kayıt yaparken mesela mesaj şöyle ise:

<Nick> merhaba ;;;; inc -uN %Kanalatekrar.text.NickMeraba 1 diye setleniyor.

sorun yok ama mesaj şöyle ise;

<Nick> Merhaba nasılsın ;;;; inc -uN %Kanalatekrar.text.NickMerhaba nasılsın

diye setlenmeye çalışıyor ki burda sayı olması lazım sayı şeklinde setlenemediği için de hata veriyor. o halde $1- yerine $remove($1-,$chr(32)) kullanayım dedim ve oldu.

Bana fikir verdiğin için saol.
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

Sevgiler... saygılar...

Alience · 29 Ağustos 2005, 17:48

birşey değil biz 6 yıldır herkeze birşeyler diyoruz ama nedense bizi hiç ipleyen olmuyor
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
.

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Tekrar korumasında Tblock	Skys	mIRC Scripting Sorunları	2	27 Eylül 2010 00:17
Sc5 Korumasında Sorun yardım Pls.	Carpediem	mIRC Scripting Sorunları	1	10 Kasım 2009 21:07
Tekrar Korumasında Sorun	morveotesii	mIRC Scripting Sorunları	3	18 Mayıs 2007 19:23
Reklam Korumasında Sorun	StanteaR	mIRC Scripting Sorunları	2	09 Mart 2007 12:17
Bad nick korumasında sorun	DomiNo	mIRC Scripting Sorunları	16	23 Eylül 2006 15:05

Konuyu Toplam 2 Üye okuyor. (0 Kayıtlı üye ve 2 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.