Tekrar koruma - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

diyorumki · 04 Kasım 2010, 12:46

on *:text:*:#: {
if $istok(%muafn,$nick,32) == $true { halt }
if $istok(%muafall,#,32) == $true { halt }
if (%tekrar == 1) && ($me isop #) && ($nick isreg #) {
if (%r. [ $+ [ $nick ] $+ . $+ [ $chan ] ] == $null) {
set -u30 %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ] 1
set -u30 %r.text. [ $+ [ $nick ] $+ . $+ [ $chan ] ] $1-
return
}
var %rps = %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
var %rpt = %r.text. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
if (%rpt == $1-) {
inc %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
if (%rps > 2) && ($nick !isop #) {
ban -u $+ %bantime # $nick 5
.kick # $nick 4 %Tekrarsebeb
inc %istabutun
inc %istatekrar
}
}
}
}

yukarıdaki codeye 1sefer uyarı bide 5dklık ipe ban bide deop ken bu komutun işlemesi için ne yapmamız lazım ?

Nothinq · 04 Kasım 2010, 13:33

Deopken yapabilmen mümkün değil, ha İrc operator veya adminsen yeterli flagın var ise olur onun dısında birak ban atmayi tek yapabilecegin şey cs'den voice vrebilmek başka birşey yapamazsin deopken
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

diyorumki · 04 Kasım 2010, 13:39

Nothinq Nickli Üyeden Alıntı
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

Deopken yapabilmen mümkün değil, ha İrc operator veya adminsen yeterli flagın var ise olur onun dısında birak ban atmayi tek yapabilecegin şey cs'den voice vrebilmek başka birşey yapamazsin deopken
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

yetkim var adminim

CesuryureK · 04 Kasım 2010, 13:50

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


on *:text:*:#: { 
if ($nick !isreg $chan) halt
hinc -mu8 # $+(#,$nick,$encode($1-)) 1
if ($hget(#,$+(#,$nick,$encode($1-))) == 2) { msg # Uyarı: $Nick Lütfen kelime tekrarı yapmayınız. }
if ($hget(#,$+(#,$nick,$encode($1-))) == 3) { .Ban -u300 # $address($nick,2) | kick # $nick $Chan kanalında verdiğim uyarıya rağmen tekrar yaptığınız için uzaklaştırıldınız.. | hdel # $+(#,$nick,$encode($1-)) }
}

Mantık;

Aop olsanızda olmasanız da 8 saniye içinde,

<User> Kelime..
<User> Kelime..
<Sen> Uyarı
<User> Kelime..
<Sen> +b User Ip ban

durumu gerçekleşecektir.

(hinc -mu8 kısmındaki 8 saniyeyi değiştirebilirsiniz ama en fazla 10 sn olsun)

Not: Hash daha hızlı olduğundan hash ile yazıp vermeyi uygun görüp kodunuzu düzeltip vermedim.

diyorumki · 04 Kasım 2010, 14:10

[14:04:42] <denemee> a
[14:04:42] <denemee> a
[14:04:42] <KORUMAA> Uyarı: denemee Lütfen kelime tekrarı yapmayınız.
[14:04:43] <denemee> a
[14:04:43] *** KORUMAA mod değiştirdi:+b
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

[14:04:43] *** denemee KORUMAA Tarafından Kanaldan Atıldı (#Help kanalında verdiğim uyarıya rağmen tekrar yaptığınız için uzaklaştırıldınız..)

usta 2 tekrarda uyarı çekti 3.de ban attı tekrar sayıyı nasıl çoğaltabiliriz 5 tekrarda atsın mesela? bide kick olmasın 5dklık ban atsın istiyorum bide benim codeye göre yapmam lazım çünkü korumalar menuden aç kapat çalışmıyor (ayrıca deopkende ban attı teşkler ilgin için )

CesuryureK · 04 Kasım 2010, 14:28

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


on *:text:*:#: { 
if ($nick !isreg $chan) halt
hinc -mu8 # $+(#,$nick,$encode($1-)) 1
if ($hget(#,$+(#,$nick,$encode($1-))) == 2) { msg # Uyarı 1 : $Nick Lütfen kelime tekrarı yapmayınız. }
if ($hget(#,$+(#,$nick,$encode($1-))) == 5) { .Ban -u300 # $address($nick,2) | hdel # $+(#,$nick,$encode($1-)) }
}

korumalarda aç kapa mantığı varsa kodunuzda grup var demektir.

#tekrar on

kodlar

#tekrar end

şeklinde olur aç kapa mantığı varsa. Sizin de yapmanız gereken kodlar kısmını verdiğim kodla değiştirmeniz.

diyorumki · 04 Kasım 2010, 15:07

aç kapa var evet ama nerden değişcek dediğin şekil

CesuryureK · 04 Kasım 2010, 18:01

Eğerki bu verdiğin kod aç kapa şeklinde işlem görüyorsa

#falanca on

kodlar

#falanca end

şeklinde bir grup kurulmuştur demiştim. aç kapa özelliğinin çalışabilmesi için böyle #falanca on #falanca end denilen gruplarına arasına kodlar konulup yapılabilmektedir.

ilk önce verdiğim kodu remotenizde bulunan kod ile değiştirin sadece paylaştığınız kısmı verdiğim kısımla değiştirin ve aç kapa şeklinde deneyin.

hala olmadığını ifade edersen;

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


#Tekrar on
on *:text:*:#: { 
if ($nick !isreg $chan) halt
hinc -mu8 # $+(#,$nick,$encode($1-)) 1
if ($hget(#,$+(#,$nick,$encode($1-))) == 2) { msg # Uyarı 1 : $Nick Lütfen kelime tekrarı yapmayınız. }
if ($hget(#,$+(#,$nick,$encode($1-))) == 5) { .Ban -u300 # $address($nick,2) | hdel # $+(#,$nick,$encode($1-)) }
} 
 
 
#Tekrar End
 
menu * { 
Tekrar Koruması
.Açık:/.enable #Tekrar | echo -a Tekrar Koruması Açıldı..
.-
.Kapalı:/.Disable #Tekrar | echo -a Tekrar Koruması Kapatıldı..
-
}

şeklinde remotenize ekleyin. Sonra mircte sağ click(tıklama) yaptığınızda menüde Tekrar koruması kısmını görüp dilediğiniz zaman açabilir veya kapatabilirsiniz.

komutla kapatıp açmak istiyorsanız.

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


#Tekrar on
on *:text:*:#: { 
if ($nick !isreg $chan) halt
hinc -mu8 # $+(#,$nick,$encode($1-)) 1
if ($hget(#,$+(#,$nick,$encode($1-))) == 2) { msg # Uyarı 1 : $Nick Lütfen kelime tekrarı yapmayınız. }
if ($hget(#,$+(#,$nick,$encode($1-))) == 5) { .Ban -u300 # $address($nick,2) | hdel # $+(#,$nick,$encode($1-)) }
} 
 
 
#Tekrar End
 
alias tekrar {
if ($1 == on) { .enable #tekrar | echo -a Tekrar Koruması Açıldı.. }
elseif ($1 == off) { .disable #tekrar | echo -a Tekrar Koruması Kapatıldı }
else { echo -a Komutu Yanlış Kullandınız. Kullanımı /Tekrar On|Off }
}

/Tekrar on : Açar
/Tekrar off : Kapatır.

İlla benim kod bu işlemleri yapsın diyorsanda,

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


on *:text:*:#: {
  if $istok(%muafn,$nick,32) == $true { halt }
  if $istok(%muafall,#,32) == $true { halt }
  if (%tekrar == 1) && ($nick isreg #) {
    if (%r. [ $+ [ $nick ] $+ . $+ [ $chan ] ] == $null) {
      set -u15 %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ] 1
      set -u15 %r.text. [ $+ [ $nick ] $+ . $+ [ $chan ] ] $1-
      return
    }
    var %rps = %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
    var %rpt = %r.text. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
    if (%rpt == $1-) {
      inc %r. [ $+ [ $nick ] $+ . $+ [ $chan ] ]
      if (%rps == 1) && ($nick !isop #) {
        msg # $nick Tekrar Yapmayın..
      }
      if (%rps  > 3) && ($nick !isop #) {
        Ban -u300 # $address($nick,2)
        inc %istabutun 
        inc %istatekrar
      }
    }
  }
}

Bakınız;

Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

diyorumki · 04 Kasım 2010, 18:26

Çok teşk ederim abim saol güzel açıklamanız için kendi kodum olanı yaptım oldu eyv

Spectral · 23 Aralık 2011, 21:41

Ayni kodlamayi "yazi tekrari" icin duzenleyebilir miyiz veya nasil duzenlenebilir ?
Ornek tekrarlar;
[18:23:32] <abc1> test tekrar
[18:23:32] <abc2> test tekrar
[18:23:32] <abc3> test tekrar
[18:23:32] <abc4> test tekrar
[18:23:32] <abc5> test tekrar
Oldugunda 3 ten fazla olan yani, abc4 ve abc5 atilabilmeli ?

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Google Play Store'daki Bir Hata, Uygulamaları Tekrar Tekrar Güncelliyor	GeN	Google	0	27 Nisan 2020 16:14
kanal koruma ve kişisel koruma addon isteği	Svs1988	mIRC Scripting Sorunları	1	05 Ekim 2011 10:34
tekrar,flood,join part farklı koruma	woody	mIRC Scripting Sorunları	4	19 Mart 2011 13:17
Büyük Harf / Uzun Harf / Tekrar Harf -Uyarı/koruma	diyorumki	mIRC Scripting Sorunları	0	06 Ekim 2010 17:22
$prot() Kanal için koruma identiferı (tekrar,flood,caps,uzun yazı,küfür,reklam vs.)	el33t	mIRC Scripting Hazır Kodlar	22	23 Mayıs 2008 00:40

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.