IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - !badnick Ekle sil Listele (https://www.ircforumlari.net/mirc-scripting-sorunlari/178237-badnick-ekle-sil-listele.html)

!badnick Ekle sil Listele

iyi sabahlar ben botuma şöyle bir şey eklemek istiyorum özelden
!badekle
!badsil
!badnick Listele

bu şekilde bi kod forumda aradımda bulamadım var ama bot için yok o yüzden bende açayım dedim:) örneğin botun özeline kanaldaki op gidecek !badekle DenperaS diye ekleyecek botta Denperas badnick listesine alınmıştır. silmeside aynı şekilde !badsil DenperaS ve !badnick Listele yazdığında listeleyecek
ben şöyle bi kod buldumda bu ekliyor nereye eklediğinide bilmiyorum ama atmıyor sadece badnick listesine eklendi yazıyor ve silindi yazıyor.

PHP- Kodu:

   on *:text:*:#Helper,#helpsop:{
  if !badekle isin $1 {
    .auser bad $2
    .msg # $2 Listeye Eklenmi?tir
  }
  if !badsil isin $1 {
    .ruser bad $2
    .msg # $2 Liste'den Silinmi?tir
  }
}

Cevap: !badnick Ekle sil Listele

Alıntı:

on *:text:*:?: {
if ($1 == !badekle) { .auser badliste $2 | $2 Listeye eklendi.. }
if ($1 == !badsil) { .ruser badliste $2 | echo -a $2 listeden silindi.. }
if ($1 == !badliste) {
var %i 1
while $ulist(*,badliste,%i) {
msg $chan $ifmatch
inc %i
}
}
}

Botun Remotesine koy bunu..

Cevap: !badnick Ekle sil Listele

kodda bir sorun yok, peki bu kodu içeren bir join eventine bağlı ban + kick kodunuz var mı ?

Alıntı:

sadece badnick listesine eklendi yazıyor ve silindi yazıyor.

dediğinize göre bu kodda bir sorun yok, çalışıyor; ki bunun için yapılmış zaten bu kod.

Kod:

on *:text:*:#Helper,#helpsop: {
   ;#helper,#helpsop kanallarındaki yazılarda

  if !badekle isin $1 {

    ;1.kelime !badekle ise

    .auser bad $2

    ;2.kelimeyi bad grubuna dakil ederek kullanıcılara ekle

    .msg # $2 Listeye Eklenmiştir

    ;kanala kelime listeye eklenmiştir  yazısı gönder.

  }

  if !badsil isin $1 {

    .ruser bad $2

    ;2.kelimeyi bad grubundaki kullanıcılar listesinden sil

    .msg # $2 Liste'den Silinmiştir

    ;kanala kelime listeden silinmiştir  yazısı gönder.

  }
   if !badlist isin $1 {

    var %s 1 

    while (%s <= $ulist(*,bad,0)) {

      msg # $ulist(*,bad,%s)

      inc %s

    } 

  }

}

Kodun açıklamasını kod içerisinde yazdım kırmızı renkli satırları okuyunuz daha da iyi anlayacaksınız. Eflatun kısmı ben ekledim , !badlist yazdığınızda eklediğiniz badnickleri verecek.

Alıntı:

ben şöyle bi kod buldumda bu ekliyor nereye eklediğinide bilmiyorum

bu kısma gelince, eklediklerinizi Script Editorundeki Kullanıcılar (Users)bölümüne ekler. eklediklerinizi bad:kelime şeklinde eklenmiş olduğunu göreceksiniz.

eğer bu kodla eklediğiniz nicklerin atılmasını istiyorsanız;

Kod:

on bad:join:#: {

  if $me isop $chan {

    mode $chan +b $nick

    kick $chan $nick Bad Nick !

  }

}

bu kodu da ekleyiniz. op olduğunuz kanallarda eklediğiniz badnickler kanala girişinde atılacaklardır.

Cevap: !badnick Ekle sil Listele

peki bunu Bot'a deyilde kendi sicript'imize kendimize göre nasıl editleriz ?

Cevap: !badnick Ekle sil Listele

Kod:

on *:input:*: {

  if !badekle isin $1 {

    .auser bad $2

    echo -a $2 Listeye Eklenmi?tir

  }

  if !badsil isin $1 {

    .ruser bad $2

    echo -a $2 Liste'den Silinmi?tir

  }

  if !badlist isin $1 {

    var %s 1 

    while (%s <= $ulist(*,bad,0)) {

      echo -a $ulist(*,bad,%s)

      inc %s

    } 

  }

}

bu şekilde kullanabilirsiniz.

Cevap: !badnick Ekle sil Listele

teşekkür ederim fenomens ilgilendiğin için. azula sanada ayrıca teşekkür ederim birde şu şekilde ekleme yapabilirmiyiz azula verdiğin badnick listesine nickin başına *nick* ekle şeklinde ekletirsem o kelimenin geçtiği nickleride banlarmı

Cevap: !badnick Ekle sil Listele

İkiside farklı şeyler. Bahsettiğin şey kelime,küfür koruma add-onlarında mevcut. Bu bizim sana gönderdiğimiz kodlar sadece giren nickleri banlar.

Alıntı:

on *:text:*:#: {
if (*küfür* iswm $1-) || (*küfür2* iswm $1-) || (*böyleçoğalt* iswm $1-) { mode $chan +b $wildsite | kick $chan $nick zımbırtı }
}

Bu kod işine yarar. Kanalda belirttiğin kelimeler geçerse banlar..

Cevap: !badnick Ekle sil Listele

sağol fenomens ama ben bota ekleyeceğim yardım kanalında badnick eklemeleri için bota azulanın verdiği kodda bunu yapabilirmiyiz badnicklerde örneğin badnick listesine des diye eklenen bir nick var ve desperas kanala girdiğinde atılsın bu şekilde olabilirmi o kodda

Cevap: !badnick Ekle sil Listele

Alıntı:

on *:input:*: {
if !badekle isin $+ * $1 $+ * {
.auser bad $2
echo -a $2 Listeye Eklenmi?tir
}
if !badsil isin $+ * $1 $+ * {
.ruser bad $2
echo -a $2 Liste'den Silinmi?tir
}
if !badlist isin $1 {
var %s 1
while (%s <= $ulist(*,bad,0)) {
echo -a $ulist(*,bad,%s)
inc %s
}
}
}

Şeklinde yaparsan eklerken *nick* silerken *nick* şeklinde işlem yapar.

Cevap: !badnick Ekle sil Listele

Alıntı:

İnFaZ Nickli Üyeden Alıntı (Mesaj 1041879300)

badlist calışmıyor ve banlananın kanala banlandıgını yazmıyor bunu diyolog şeklinde yapsak olurmu peki ?

Kod:

alias Shitlist {  if ($dialog(Shitlist)) { dialog -c Shitlist } |  dialog -ma Shitlist Shitlist }

dialog Shitlist {

  size -1 -1 295 346

  title "Blacklist"

  Combo  1,  1 1 240 330

  button "&Ekle",  2,  244 2 50 22

  button "&Cıkar",  3,  244 24 50 22

  button "Tamam",  4,  244 324 50 22,ok

  Check  "Shitlist Açık" , 5 , 1 327 241 20

}

on *:dialog:Shitlist:*:*: {

  if ($devent == init) { Shitlist.init }

  if ($devent == sclick) {

    if ($did == 2) { if ($did(1) != $null) { /.auser blacklist $did(1)  | Shitlist.init } }

    if ($did == 3) { if ($did(1) != $null) { /.ruser $did(1)  | Shitlist.init } }

    if ($did == 5) { 

      if ($did(5).state == 1) {  writeini " $+ $mircini $+ " Shitlist Shitlist on }

      if ($did(5).state == 0) {  writeini " $+ $mircini $+ " Shitlist Shitlist off }

    }

  }

}
 

alias Shitlist.init {

  did -r Shitlist 1

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { did -c Shitlist 5 }

  set %ul 1 

  while (%ul <= $ulist(*,0)) {

    if ($level($ulist(*,%ul)) == blacklist) {  did -a Shitlist 1 $ulist(*,%ul)  }

    inc %ul 1

  }

  unset %ul

}

on blacklist:join:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $nick %Shitlist %logo

    }

  } 

}
 

on blacklist:part:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick 

    }

  } 

}

on blacklist:nick: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $newnick %Shitlist %logo

    }

  } 

}
 

on blacklist:text:*:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $nick %Shitlist %logo 

    }

  } 

}

on blacklist:notice:*:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $nick %Shitlist %logo

    }

  } 

}

on blacklist:action:*:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $nick %Shitlist %logo

    }

  } 

}
 

on blacklist:op:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $opnick %Shitlist %logo

    }

  } 

}

on blacklist:deop:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $opnick %Shitlist %logo

    }

  } 

}
 

on blacklist:voice:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      ban # $vnick 2 | kick $chan $vnick %Shitlist %logo

    }

  } 

}
 

on blacklist:devoice:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      ban # $vnick 2 | kick $chan $vnick %Shitlist %logo

    }

  } 

}
 

on blacklist:help:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      ban # $hnick 2 | kick $chan $hnick %Shitlist %logo

    }

  } 

}
 

on blacklist:dehelp:#: {

  if ($readini " $+ $mircini $+ " Shitlist Shitlist == on) { 

    if (($me isop $chan) || ($me ishelp $chan)) { 

      mode # +b $nick | kick $chan $hnick %Shitlist %logo

    }

  } 

}

Alıntıdır. Önceden kullanıyordum bunu kullanabilirsin.

/shitlist yazarak ekleme yapacağın pencereyi açabilirsin

Aliases kısmına aşağıdaki kodu eklereyerek kanalda gördüğün nicki seçip F11 e basarak listeye ekleyebilir ve kanaldan atabilirsin.

F11 .auser blacklist $$1 | kick # $$1 Shitlisted.. eklenen nick: $$1 | echo $$1 Shitlistesine EkLenmistir...