cinsel kanal koruması yardım - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Susuntu · 23 Aralık 2008, 02:32

iyi geceler elimde bir kod var

menu status,channel {
.-
.Cinsel Kanal Korumaları
..Korumayı Devreye Al !:.enable #whoisaclan | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devrede
..Korumayı Devre Dışı Bırak !:.disable #whoisaclan | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devre Dışı
.-
}
#whoisaclan off
on @*:join:#:whois $nick
raw 319:*: { if (*** isin $1- ) || (cinsellik isin $1- ) || (gay isin $1- ) || (lezbiyen isin $1- ) || (evli isin $1- ) || (bayan isin $1- ) { var %x = $comchan($2,0)
{ if ($me isop $comchan($2,%x)) { ban -u200 $comchan($2,%x) $2
.kick # $comchan($2,%x) $2 10 Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir. } | dec %t } } }
#whoisaclan end

böyle bir cinsel içerikli kanal koruması açıkçası pek anlamıyorum bu yüzden yardımlarınızı bekliyorum ben bunu bir panel haline getirmek istiyorum panelde korumayı aç kapat ve oraya kanalda eklemek istiyorum örneğin cinsellik kanalı var ben oraya kanal ekle dediğimde kanalı yazacağım ve sonra o kanaldandan girenleride atacak belki çok şey istiyorum ama bunu yapmamda yardımcı olurmusunuz

Difuzyon · 23 Aralık 2008, 04:45

Kod: Kodu kopyalamak için üzerine çift tıklayın!

#whoisacarmısın on
on @*:join:#:whois $nick | .enable #gecegece
raw 319:*: {
  haltdef
  var %jnk 1
  while $ulist(*,badkanal,%jnk) {
    if $istok($remove($3-,:,+,%,@,&,~,.),$ifmatch,32) { 
      var %x = $comchan($2,0)
      while %x { 
        if ($me isop $comchan($2,%x)) { 
          ban $comchan($2,%x) $2 2
          .kick $comchan($2,%x) $2 10Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir. 
        }
        dec %x 
      } 
    } 
    inc %jnk
  }
}
#whoisacarmısın end
#gecegece off
raw 311:*:haltdef   
raw 312:*:haltdef
raw 307:*:haltdef
raw 317:*:haltdef
raw 318:*:haltdef | .disable #gecegece
#gecegece end 
alias cinselkanal if $dialog(BadKanal) == $null dialog -m BadKanal BadKanal
dialog BadKanal {
  title "Cinsel Kanal giriş koruma"
  size -1 -1 200 265 
  button "Tamam", 1, 110 200 70 20,ok
  list 2, 10 20 180 135, sort 
  box "Cinsel Kanal", 3, 5 5 190 145 
  edit "#", 4, 10 165 180 20, autohs
  box "Eklenecek #kanal 'ı girin", 5, 5 150 190 45
  button "Ekle", 6, 20 200 70 20
  box "Not:", 7, 5 225 190 35 
  text "Silmek için #kanala çift tıklayın", 8, 25 240 180 45 
}
on *:dialog:BadKanal:dclick:2:{ .ruser badkanal $did(2).seltext | did -d BadKanal 2 $did(2).sel }
on *:dialog:BadKanal:sclick:6:{ if ($did(4) != $null) { did -a BadKanal 2 $did(4) | .auser badkanal $did(4) | did -fr BadKanal 4 } }
on *:dialog:BadKanal:init:*:{ 
  if ($ulist(*,badkanal,0) != $null) { 
    set %cinsel 0
    while (%cinsel < $ulist(*,badkanal,0)) { 
      inc %cinsel 1 
      did -a BadKanal 2 $ulist(*,badkanal,%cinsel) 
    } 
    unset %cinsel 
  } 
} 
menu status,channel {
  .-
  .Cinsel Kanal Korumaları
  ..Korumayı Devreye Al !:.enable #whoisacarmısın | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devrede
  ..Korumayı Devre Dışı Bırak !:.disable #whoisacarmısın | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devre Dışı
  ..Cinsel Kanal Ekle-Çıkar !:cinselkanal
  .-
}

Kodu (ALT + R) ile açılan panelde REMOTE başlığına ekliyorsunuz.
Daha önce paylaşılmış olan bi dialogu(paylaşan, neverbackdown) sizin istediğiniz gibi dizayn ettim.(Tşk. neverbackdown)

Op olduğunuz kanalda,koruma açıksa giren nicke whois çekecektir. Eklediğiniz kanallardan birini görürse işte o zaman affetmicektir
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

Ben baya bir test ettim ama kullanışa bağlı olarak sorun yaşarsanız yine bu başlık altından belirtirsiniz.

Hoşca paylaşımlar...

Susuntu · 23 Aralık 2008, 05:02

çok tşk ederim Difuzyon hoşçakal

Susuntu · 24 Aralık 2008, 08:51

tekrar merhaba Difuzyon ben bu kodu daha önce kullanıyordum şöyleydi bu kod
örneğin cinsellik kanlı ekliydi cinsellikle ilgili tüm kanalları atardı cinsellik1 cinsellika cinsellikb cinsellik2 gibi içinde cinsellik geçen bütün kanalları atıyordu ama senin verdiğin atmıyor eskisi gibi atması için ne yapmalıyım.

Difuzyon · 24 Aralık 2008, 13:26

if $istok($remove($3-,:,+,%,@,&,~,.),$ifmatch,32) {

satırını silip, yerine aşağıdakini yazmanız yeterlidir:

if $ifmatch isin $remove($3-,:,+,%,@,&,~,.) {

DenperaS · 11 Şubat 2009, 20:58

merhaba kolay gelsin bu korumaya !cinseltara yaptığımızda cinsel içerikli kanallarda bulunanları atabilirmi.

Difuzyon · 11 Şubat 2009, 23:33

Kod: Kodu kopyalamak için üzerine çift tıklayın!

#whoiscns off
raw 319:*: {
  .haltdef
  var %jnk 1
  while $ulist(*,badkanal,%jnk) {
    if $ifmatch isin $remove($3-,:,+,%,@,&,~,.) { 
      ban -k %channels $2 2 Dışarı..
    }
    inc %jnk 
  }
}
#whoiscns end
on *:input:#:{
  if $1 == !cinseltara && $me isop $active {
    set %channels $chan
    .enable #whoiscns
    .timer 1 15 .disable #whoiscns $(|) unset %channels
    var %cnk 1
    while %cnk <= $nick($chan,0) {
      if $me != $nick($chan,%cnk) { whois $nick($chan,%cnk) }
      inc %cnk
    }
  }
}

Mevcut olan korumaya özgü bir çalışma.
@ olduğunuz kanala !cinseltara yazdığınızda kanalın hepsine whois çekecektir.Uygun olmayan kanalları saptarsa,nicki(leri) kanaldan atacaktır.Kanal çok kalabalıksa kasabilir,sık kullanmamak gerekir...

DenperaS · 12 Şubat 2009, 02:49

difuzyon ben bunu ekledim fakat herhangi bir tarama yapmadı. user bölümen badkanal olarak ekledim sonra bu kodu herhangi bi txt dosyasına attım ve tanıttım sonra op olduğum kanaldada !cinseltara yazdım ama kimseye whois çekip atmadı sanırım sorun bende. anlatabilirmisin bunu nasıl ekleyeceğiz ve tarama yaptırabileceğim bota

Lucifer · 12 Şubat 2009, 08:31

DenperaS Nickli Üyeden Alıntı
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

difuzyon ben bunu ekledim fakat herhangi bir tarama yapmadı. user bölümen badkanal olarak ekledim sonra bu kodu herhangi bi txt dosyasına attım ve tanıttım sonra op olduğum kanaldada !cinseltara yazdım ama kimseye whois çekip atmadı sanırım sorun bende. anlatabilirmisin bunu nasıl ekleyeceğiz ve tarama yaptırabileceğim bota

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


#whoisacarmısın on
on @*:join:#:whois $nick | .enable #gecegece
raw 319:*: {
  haltdef
  var %jnk 1
  while $ulist(*,badkanal,%jnk) {
    if $istok($remove($3-,:,+,%,@,&,~,.),$ifmatch,32) { 
      var %x = $comchan($2,0)
      while %x { 
        if ($me isop $comchan($2,%x)) { 
          ban $comchan($2,%x) $2 2
          .kick $comchan($2,%x) $2 10Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir. 
        }
        dec %x 
      } 
    } 
    inc %jnk
  }
}
#whoisacarmısın end
#gecegece off
raw 311:*:haltdef   
raw 312:*:haltdef
raw 307:*:haltdef
raw 317:*:haltdef
raw 318:*:haltdef | .disable #gecegece
#gecegece end 
alias cinselkanal if $dialog(BadKanal) == $null dialog -m BadKanal BadKanal
dialog BadKanal {
  title "Cinsel Kanal giriş koruma"
  size -1 -1 200 265 
  button "Tamam", 1, 110 200 70 20,ok
  list 2, 10 20 180 135, sort 
  box "Cinsel Kanal", 3, 5 5 190 145 
  edit "#", 4, 10 165 180 20, autohs
  box "Eklenecek #kanal 'ı girin", 5, 5 150 190 45
  button "Ekle", 6, 20 200 70 20
  box "Not:", 7, 5 225 190 35 
  text "Silmek için #kanala çift tıklayın", 8, 25 240 180 45 
}
on *:dialog:BadKanal:dclick:2:{ .ruser badkanal $did(2).seltext | did -d BadKanal 2 $did(2).sel }
on *:dialog:BadKanal:sclick:6:{ if ($did(4) != $null) { did -a BadKanal 2 $did(4) | .auser badkanal $did(4) | did -fr BadKanal 4 } }
on *:dialog:BadKanal:init:*:{ 
  if ($ulist(*,badkanal,0) != $null) { 
    set %cinsel 0
    while (%cinsel < $ulist(*,badkanal,0)) { 
      inc %cinsel 1 
      did -a BadKanal 2 $ulist(*,badkanal,%cinsel) 
    } 
    unset %cinsel 
  } 
} 
menu status,channel {
  .-
  .Cinsel Kanal Korumaları
  ..Korumayı Devreye Al !:.enable #whoisacarmısın | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devrede
  ..Korumayı Devre Dışı Bırak !:.disable #whoisacarmısın | .echo -a 0,4 Cinsel İçerikli Kanal Korumaları Devre Dışı
  ..Cinsel Kanal Ekle-Çıkar !:cinselkanal
  .-
}
#whoiscns off
raw 319:*: {
  .haltdef
  var %jnk 1
  while $ulist(*,badkanal,%jnk) {
    if $ifmatch isin $remove($3-,:,+,%,@,&,~,.) { 
      ban -k %channels $2 2 Dışarı..
    }
    inc %jnk 
  }
}
#whoiscns end
on *:input:#:{
  if $1 == !cinseltara && $me isop $active {
    set %channels $chan
    .enable #whoiscns
    .timer 1 15 .disable #whoiscns $(|) unset %channels
    var %cnk 1
    while %cnk <= $nick($chan,0) {
      if $me != $nick($chan,%cnk) { whois $nick($chan,%cnk) }
      inc %cnk
    }
  }
}

Örnek;

Normal Operatör'ler İçin Örnek;

[08:16] <NeverBackDown> !cinseltara
[08:16] * NeverBackDown sets mode: +b
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

[08:16] * NeverBackdown1 was kicked by NeverBackdown (Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir.)

IRCop ve Administratorler;

Örnek ;
[08:16] <NeverBackDown> !cinseltara
[08:16] * NeverBackDown sets mode: +b
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

[08:16] * Quits: NeverBackdown1 (never@XXXX) ([IRC.XXXx.Net] Local kill by NeverBackdown (Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir.))

- Codeyi bu şekilde ALT +R Yaparak mIRC'ine ekle sonra normal kanalda sağ tıkladığında Cinsel Kanal Korumalari diye bir bölüm açılacak, Oraya gelip cinsel kanal ekle, çıkar bölümüne cinsel içerikli kanallari yazarsan, koruma çalişacaktır.

- Bu şekilde düzelttikden sonra deneyin çalışacaktır.

- Eğerki IRCop veya Administrator Yetkin var ise; kill olarakda yapabilirsin cinsel içerikli kanallar'da olanlar senin Op olduğun odalara giriş yaptiğinda kill yer ve banlanır; onun içinse aşağıdaki gösterilen yeri.

Kill İçin;

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


ban $comchan($2,%x) $2 2
.kill $2 10Cinsel İçerikli Kanallarda Bulunduğunuz İçin Bu Kanala Girişiniz Süresiz Olarak Engellenmiştir.

iyi Forumlar..

Havana-NYX · 10 Mart 2009, 07:10

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] verdiğiniz kod çalışıyor yalnız bazı sorunları var.
1-) Kodu eklediğimiz zaman kullanıcılara manuel whois çektiğimiz zaman hiç bir kanalda değilmiş gibi gözüküyor.
2-) Op olduğumuz bir kanala giriş yaptıktan sonra tarama yaptığımızda whoislerde hiçbir kanala giriş yapılmadığını gösterdiği için cinsel içerikli kanalda bulunanları atmıyor.

NOT 1: Mynet serverında denenmiştir.
NOT 2: mIRC Script'i çok iyi bilmiyorum bende de hata olabilir.
İstek: !cinseltara 'yı menü olarak eklersek çok şık olur düşüncesindeyim
İlgi ve alakanız için şimdiden teşekkür ederim...

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Proxy Koruması yardım	STyLo	mIRC Scripting Sorunları	4	31 Ocak 2011 00:03
Kanal Flood Koruması	SovaLyem	mIRC Scripting Hazır Kodlar	10	05 Ocak 2011 17:19
tekrar koruması yardım	DenperaS	mIRC Scripting Sorunları	2	14 Haziran 2010 12:06
basit ßi kanal koruması	MaeLStrOm	mIRC Scripting Sorunları	4	15 Nisan 2005 12:20
Kötü KanaL Koruması....	Mack	mIRC Scripting Sorunları	8	13 Mart 2005 14:19

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.