[Prens]

Merhaba kıymetli İF,
Badnick ve Taraması hakkında bir çok konu var araştırdım, bende ki Badnick korumasına uygun Badnick Tarama bulamadım. Bu konuda yardımcı olabilir misiniz lütfen?

Mevcut kullanmakta olduğum Badnick Koruması;

Kod:   Kodu kopyalamak için üzerine çift tıklayın!

alias control {
  if $chan(0) >= 1 { set %difi $regsubex($dde(mirc,channels),/\*/,$null) }
  who +c $token(%difi,1,32)
}
raw 352:*:{ 
  if %difi {
    haltdef
    if $regex($level($6),/^(bad|blacklist)$/) { 
      ;Muaf #Kanal(lar) alttaki satıra eklenmeli.
      if ($istok(#kanal1 #kanal2 #kanal3,$2,32)) { halt } 
      if ($me isop $2 || $me ishop $2) { mode $2 +b $6 | kick $2 $6 Badnickler dışarı! }
      else { echo 06 -a $+([,$2,]) kanalında $qt($6) badnick tanımına uyuyor }
    }
  }
}

raw 315:*:{
  if %difi {
    haltdef
    set %difi $deltok(%difi,1,32)
    if $numtok(%difi,32) == 0 { unset %difi }
    else { who +c $token(%difi,1,32) }
  }
}

alias -l _buser { .guser blacklist $1 3 }
alias -l _rbuser { .ruser blacklist $1 3 }
alias -l _luser { dialog -m _blacklist _blacklist }
alias -l _blist {
  did -r _blacklist 11
  var %_btotal = $ulist(*,blacklist,0) , %_b = 0
  while (%_b < %_btotal) {
    inc %_b
    did -a _blacklist 11 $ulist(*,blacklist,%_b)
  }
}
alias karaliste /dialog -m _blacklist _blacklist
dialog _blacklist {
  title "Yasaklı Rumuz Listesi"
  size -1 -1 150 110
  option dbu
  text "Yasaklı Rumuz Ekleyin:" , 10 , 10 5 95 10 , left
  combo 11 , 10 15 95 85 , extsel sort autohs autovs
  edit "" , 12 , 10 95 95 10 , read autohs
  button "&Ekle" , 20 , 115 35 30 20 ,flat
  button "&Sil" , 30 , 115 60 30 20 , flat
  button "Tamam" , 40 , 115 85 30 20 , ok, flat
}
on *:dialog:_blacklist:init:*: {
  _blist
}
on *:dialog:_blacklist:sclick:*: {
  if ($did == 20) {
    if ($did(11).text != $null && $level($did(11).text) != blacklist) {
      var %_badd = $did(11).text
      .auser blacklist %_badd
      _blist
      did -o $dname 12 1 %_badd listeye eklendi.
    }
  }
  if ($did == 30) {
    if ($did(11).text != $null && $level($did(11).text) == blacklist) {
      var %_brem = $did(11).text
      .ruser blacklist %_brem
      _blist
      did -o $dname 12 1 %_brem listeden silindi.
    }
  }
}
#bd on
on !*:join:#: { 
  if ($istok(nick1 nick2 nick3 TestOyun Radyo Kelime Oyuncu Global NickServ MemoServ ChanServ Administrator,$nick,32)) { halt }
  if ($nick isop #) || ($istok(#mirchelp #help #kontrol #bilgi #op #yönetim #operhelp #cinsellik #bulsende #oyun #bulmaca #yarisma #eglence,#,32)) return
  if ($chan == #cinsellik) { halt }
  if $ulist($nick,blacklist,*) || $ulist($nick,Filtre,*) { mode $chan +b $nick $+ !*@* | kick $chan $nick Uygunsuz rumuz kullanmak yasak! } 
}

#bd end
menu * {
  Badnick - Ayarlar
  .Dialog Aç:/karaliste
  .Aç:.enable #bd | echo -a $timestamp Badnick Koruması (Açık)
  .Kapat:.disable #bd | echo -a $timestamp Badnick Koruması (Kapalı)
  .BadTara:.control
  .Durum< $iif($group(#bd) = on, Açık , Kapalı ) > :.
}