[L4roXyL]

Yazan: L4roXyL - Hasan AYDENİZ
Tarih: Eski kodlarımdan.

-

Kullanım: /inuser <nick> <sunucu.uzantısı>
Örnek kullanım: /inuser l4roxyl chat.com.tr
İşlev: Belirlediğiniz nicki, belirlediğiniz sunucu üzerinde arar. Eğer aranan nick sunucuda mevcut ise, (whois)bilgilerine ulaşabilirsiniz. (bağlantı socket olarak gerçekleşir)

-

Kod:   Kodu kopyalamak için üzerine çift tıklayın!

alias inuser {
  $iif($hget(nick),hfree nick) | unset %net | var %e = echo $color(info text) -ste * /inuser: Hatalı veya eksik kullanım: 
  if (!$1 || !$2) { %e /inuser <nick> <network> | return }
  if ($regex($1,(?<=^\d)) && $regex($1,(\w{1,30}))) { %e IRC  sunucularında herhangi bir nick <rakam> ile başlayamaz. | return }
  if (!$regex($2,(\w{3,})(\.{1})(\w{2,}))) { %e Sunucu adresini $+(%,80) oranında yanlış girdiniz. | return }
  var %irc = $+(irc.,$2) | set %net %irc | hadd -m nick $1 1 
  if (%irc != $sock(inuser).addr) { $iif($sock(inuser),sockclose inuser)  | sockopen inuser %irc 6667 } | else sockwrite -n inuser ison $1
  echo $color(info text) -st * /inuser: $qt($1) rumuzu $qt(%irc) sunucusunda aranıyor.
}
on *:sockopen:inuser: {
  var %s = sockwrite -n $sockname,%n = $+($hget(nick,1).item,$r(0,99)),%id = $+(Kontrol,$r(1,9999))
  if ($sockerr) { echo $color(info text) -ste Sunucuya bağlanılamadı. Kontrol ederek tekrar deneyiniz. | return }
  %s NICK %n | %s USER mIRC * * $+(:,%id) | sockmark $sockname %n
}
on *:sockread:inuser: {
  if ($sockerr) { echo $color(info text) -ste Sunucuya bağlanılamadı. Kontrol ederek tekrar deneyiniz. | return }
  sockread %: | tokenize 32 %: | var %n: = $regsubex($token($1,1,33),:,)
  if ($regex($2,^PRIVMSG$) && $regex($3,$sock($sockname).mark) && $regex($4-,VERSION))  {
    sockwrite -n $sockname notice %n: : VERSION mIRC $version Khaled Mardam-Bey 
  }
  if ($regex($1,^PING$)) { sockwrite -n $sockname pong $2- }
  if ($regex($2,^JOIN$) && %n: == $sock($sockname).mark) { sockwrite -n $sockname part $regsubex($3,:,) }
  if ($regex($2,^001$)) { sockwrite -n $sockname ison $hget(nick,1).item } 
  if ($regex($2,^303$) && $3 == $sock($sockname).mark) {
    if ($regsubex($4,:,) == $hget(nick,1).item) { echo $color(info text)  -ste * /inuser: Aradığınız $qt($hget(nick,1).item) rumuzu, $qt(%net)  sunucusunda online. Bilgilerini görüntülemek için; $qt(tıklayın.) }
    else echo $color(info text) -ste * /inuser: Aradığınız $qt($hget(nick,1).item) rumuzu, $qt(%net) sunucusunda bulunmuyor. 
  }
  if ($3 == $sock($sockname).mark && $4 == $hget(nick,1).item) { 
    if ($regex($2,^401$)) { echo $color(info text) -st * /inuser:  $qt($4) bilgileri alınamadı. (Nick değiştirmiş veya çıkmış olabilir) }
    if ($regex($2,^311$)) { echo -st Adresi: $+($chr(2),$4,!,$5,@,$6) | echo -st Gerçek isim: $+($chr(2),$right($8-,-1)) }
    if ($regex($2,^307$)) { echo -st Kayıt bilgisi: $+($chr(2),Kayıtlı ve kullanılamaz nick.) }
    if ($regex($2,^319$)) { echo -st Bulunduğu kanallar: $+($chr(2),$right($5-,-1)) }
    if ($regex($2,^313$)) { echo -st INFO: $+($chr(2),$7-) }
    if ($regex($2,^317$)) { echo -st Konuşmadığı süre:  $+($chr(2),$duration($5)) | echo -st Bağlantı zamanı:  $+($chr(2),$asctime($6,dd/mm/yy - hh:nn:ss)) }
    if ($regex($2,^318$)) { echo -ste $+($chr(2),$hget(nick,1).item,$chr(2)) rumuzunun bilgi sonu. } 
  }
}
on ^*:hotlink:*"tıklayın."*:status window:if ($1 == $qt(tıklayın.)) return
on *:hotlink:*"tıklayın."*:status window:if ($sock(inuser).status) {  echo -ste $+($chr(2),$hget(nick,1).item,$chr(2)) rumuzunun bilgileri  sıralanıyor. | sockwrite -n inuser whois $hget(nick,1).item }

Ekran resmi:

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

-

İşinize yarar. Geliştirebilirsiniz canım.

[amasyaLi]

-N Unknown command
-
-N Unknown command

Böyle uyarı veriyor olmadı yardımcı olabilirmisin niyetim konuyu hortlatmak değildi
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

[L4roXyL]

Bu şekilde bir hata vermesi için kodda herhangi bir sorun yok.
Senin gösterdiğin sorun /-n şeklinde bir komut girmeye çalışıyor. Kodda "-n" ile alakalı olan şeyler /sockwrite komutu ile beraber uygulanan bir parametredir. Yüksek ihtimal ile sen herhangi bir satırda /sockwrite komutunu kaldırmışsındır veya eksik ekleme yapmışsındır.

Bunun dışında kodda ilk başta dediğim gibi herhangi bir sorun yok.

[amasyaLi]

teşekkürler L4roXyL başka bir mircte denedim gayet sağlıklı çalışıyor. Başarılar dilerim

[fav]

kod güzel eline sağlık şöyle birşey mümkünmü
//:sockwrite -n inuser PRIVMSG $hget(nick,1).item $$?="mesajınız:"
ile mesaj yollanıyor

peki karşı taraf cvp verince bana nasıl ulaşıcak mesaj
nasıl bir kod lazım

[OperServ]

Super bise eline saglik basarilarin devamini dilerim.

[devil-boyy]

Başarılar Bu Kodu SamSunLu Nickli Bir Rootta Görmüştüm Dediğiniz Gibi eskilerden Eline Sağlık

[Ka2N]

peki bu ident korumalı olan serverlerde geçerli mi ?

[POSOFxPOWER]

Guzel calismaya benziyor ama bende calismadi, bikac farkli serverlerde
CR ve unrealde denedim. bu hatayi veriyor


[04:39] * /inuser: "deneme33" rumuzu "irc.blabla.Com" sunucusunda aran?yor.
-
[04:39] * /inuser: Arad???n?z "deneme33" rumuzu, "irc.blabla.Com" sunucusunda online. Bilgilerini görüntülemek için; "t?klay?n."
-
* Invalid format: $+

[ZaLiM1979]

tebrikler..

simdi denedim süper calisiyor..