IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Yazan: L4roXyL - Hasan Aydeniz
Tarihleri: Değişik vs.(eski kodlar)

-

$_text($1-)

Açıklama: Biliyorsunuz, scripting ile uğraşanlarda en çok merak edilen veya sorulan şeylerden birisi "bu kelime kaçında kelime oluyor?" "burada/bu cümlede $3 hangisi olur?" İşte bu tür soruların geneli için bir alias oluşturdum.

Kod:

alias _text if ($isid) return $regsubex($$1-,/(?<=^|\s)(.)/g,$+($chr(40),$,\n,$chr(41))\t)

-

Örnek: //echo -: $_text(Bu bir denemedir.)
Sonuç: ($1)Bu ($2)bir ($3)denemedir.

-

$ascii(text|asciivalue [.][..]) - Prop: value, ascii

Kullanımlar:

$ascii(text).ascii => text kısmına girilen yazının ascii kodlarını verir.
$ascii(ascivalue ascivalue [.] [..]).value => ascivalue kısmına girilen ascii numaralarını text-e çevirir.

-

Kod:

alias ascii {

  if ($show && !$prop && !$isid) { echo -eca info *  hatalı kullanım: $!ascii(text).ascii ve/ya $!ascii(ascivalue ascivalue  [.] [..]).value | return } 

  if ($prop = ascii) return $regsubex($1-,/(.)/g,$chr(32) $asc(\1))

  if ($prop = value) return  $regsubex($regsubex($regsubex($regsubex($1-,/(32|160)/g,-),/(\d{1,3})/g,$chr(\1)),/\s/g,),/(-)/g,$chr(32))

}

Örnekler:

//echo -: $ascii(deneme).ascii => 100 101 110 101 109 101
//echo -: $ascii(100 101 110 101 109 101).value => deneme

-

$trans(harf|rakam)

Açıklama: Girilen harfin alfabede kaçıncı sırada olduğunu, veya girilen numaranın alfabede hangi harfe eşleştiğini gösterir.
Not: Geliştirime göre, text şifreleme-şifrelenen texti geri çevirme vb. şeyler yapabilirsiniz.

Kod:

alias trans {

  if ($isid) {

    var %q = echo $color(info text) * [$!trans] Hatalı kullanım. | if (!$1) { %q | halt }

    var %alpha = a\b\c\ç\d\e\f\g\ğ\h\ı\i\j\k\l\m\n\o\ö\p\r\s\ş\t\t\ü\v\y\z\x\q\w,%num = $regsubex($str(_,32),/(.)/g,$+(\n,\))

    if ($regex($1,^([a-zA-ZğĞüÜşŞıİçÇöÖ]{1})$)) return Trans: $1 - $token(%num,$findtok(%alpha,$1,1,92),92) 

    if ($regex($1,^(\d{1,2})$)) return Trans: $1 - $token(%alpha,$findtok(%num,$1,1,92),92) 

    else return Trans: $1

  }

  else echo $color(info) * /trans olarak kullanıma kapalıdır. Kullanım şekli: $!trans(harf|rakam)

}

Örnek: $trans(z) => 29 - $trans(29) => z

-

/userh <#channel> <username>

Açıklama: Belirlediğiniz kanaldaki, belirlediğiniz kullanıcının ileti geçmişini görüntülemenize yarayacak bir kod.

-

Kod:

alias userh {

  if (!$regex($1,^#+) || !$2) { echo $color(info text) -e * /userh:  Hatalı kullanım: /userh <#channel> <user> | returnex }

  var %1 = 1,%2 = $line($1,0), $& 

    %n = $regsubex($2,/(\[|\]|\^|\||\\)/g,$+(\,\1)\s) | while (%1 <= %2) { 

    if ($regex($gettok($line($1,%1),1,32),$+(<?,%n,>)) || $regex($gettok($line($1,%1),2,32),$+(<?,%n,>))) { 

      inc %c $len($line($1,%1)) | inc %cc | win $1 $2 $line($1,%1) 

    } 

    inc %1 

  } 

  if ($window(@-)) { aline @- - | aline @- Toplam gönderdiği satır: %cc - Toplam karakter: %c | unset %c %cc | return }

  echo $color(info text) -ate $1 kanalında, $2 rumuzu için konuşma kaydı bulunamadı.

}

alias -l win if (!$window(@-)) { window -aCdlk0 +l @- | aline @- - $2  rumuzunun $1 kanalındaki konuşma kaydı: | aline @- - | titlebar @- $2  konuşma kaydı. } | aline -p @- $3-

-

İşinize yarar.
Hasan AYDENİZ