ip notify alma Hakkinda
 

Selam arkadaslar Mesala elimde Söle bir ip numarası var 9D069AB.E021A995.A22238CE.IP bunu notify e alabilmek mumkunmudur ?? Yani nete başka bir nickle nete aynı ip ile girse bile haber almak istiyorum.. Yardımcı olursanız şimdiden tşkler..

Cevap: ip notify alma Hakkinda
 

tam aradığın şey mi bilmiyorum ama çok kullanışlı bir kod burdan almıştım yapımcısını büyük ihtimalle yabancı ben kendime göre türkçe yapmıştım 9D069AB.E021A995.A22238CE.IP bu kısmı ana klasorde "trackusers" klasore eklıyo ve daha önce kullandığı nickleri gösteriyo. nicklistte sağ tıklayınca listeden kaldırma falan var bence işine yarayacaktır.


ON *:START: {
; Create a hash table and load the saved user data
hmake trackusers 10
if ($isfile(trackusers.dat)) {
hload trackusers trackusers.dat
}
}
on *:JOIN:#: {
; Check if there are any nicknames for this mask
if ($hget(trackusers,$address($nick,3))) {
var %n = $ifmatch
; Delete the current nickname from the list of used nicknames
if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
else { var %d = %n }
; If there are no nicknames left in the list then stop
if (!%d) { return }
; Display the nicknames
echo $colour(info) -ti2 $chan * $nick 6Daha önce kullandığı Nickler12 $+ $iif($numtok(%d,32) > 1,:,:) %d
if (!$istok(%n,$nick,32)) {
; Add the current nickname to the list
hadd trackusers $address($nick,3) %n $nick
}
}
else {
; Create a new entry for this mask
hadd trackusers $address($nick,3) $nick
}
}
on *:NICK: {
if ($hget(trackusers,$address($newnick,3))) {
var %n = $ifmatch
if (!$istok(%n,$newnick,32)) {
; Append the new nickname to the list for this mask
hadd trackusers $address($newnick,3) %n $newnick
}
}
else {
; Create a new entry for this mask
hadd trackusers $address($nick,3) $newnick
}
}
menu nicklist {
Track Users
.Daha önce kullandığı nickler:{
if (!$address($$1,3)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
if ($hget(trackusers,$address($$1,3))) {
var %n = $ifmatch
if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
else { var %d = %n }
if (!%d) { goto notknown }
echo $colour(info) -ti2 # * $$1 4Daha önce kullandığı Nickler12 $+ $iif($numtok(%d,32) > 1,:,:) %d
}
else {
:notknown
echo $colour(info) -ti2 # * $$1 4Daha önce başka nick kullanmamıştır! 12
}
}
; This resets the data for this nick's mask only
.Reset:hdel trackusers $address($$1,3)
}
ON *:EXIT: {
; Save data on exit
if ($hget(trackusers)) { hsave -o trackusers trackusers.dat }
}

Cevap: ip notify alma Hakkinda
 

Deneyeceğim arkadaşım ilgine tşkler..

Cevap: ip notify alma Hakkinda
 

tşk