;############################# ARKADAŞ LİSTESİ ######################################


menu channel,status,menubar,query {
  -
  Arkadaş Listesi { dialog -m arkadaslist arkadaslist }
  -
}

;- Arkadaş Listenizde ekli kişiye #Sohbet kanalın 'da (+v) verirsiniz.
#arkadaslist on
on arkadaslist:join:#Sohbet:{
  .mode # +v $nick
  .msg $nick $_bilgi(Bilgilendirme Mesajı: Arkadaş listesine ekli kullanıcı kanalda (+) 'landı.)
  $iif(!$window(@Q-Takip),.window -zne @Q-Takip)
  .echo -em @Q-Takip $_gri($_tarih) $_baslik2(Arkadaş Listesi) $_kirmizi(Nick/IP: $nick - @ $+ $_ndr($nick)) $_bilgi(Arkadaş listesine ekli kullanıcı kanalda (+) 'landı.) $_sari(#) $_yesil($network)
}
on *:NICK:{
  if ($level($newnick) == arkadaslist) {
    var %:chans = $comchan($newnick,0) | while %:chans {
      if $istok(#Sohbet,$comchan($newnick,%:chans),44) { 
        .mode $comchan($newnick,%:chans) +v $newnick 
        $iif(!$window(@Q-Takip),window -zne @Q-Takip)
        .echo -em @Q-Takip $_gri($_tarih) $_baslik2(Arkadaş Listesi) $_kirmizi(Nick/IP: $newnick - @ $+ $_ndr($nick)) $_bilgi(Arkadaş listesine ekli kullanıcı kanalda (+) 'landı.) $_sari($comchan($newnick,%:chans)) $_yesil($network)
      }
      dec %:chans
    }
    .msg $newnick $_bilgi(Bilgilendirme Mesajı: Arkadaş listesine ekli kullanıcı kanalda (+) 'landı.)
  }
}
#arkadaslist end

alias arkadaslist { /dialog -m arkadaslist arkadaslist }
dialog arkadaslist {
  title "Arkadaş Listesi"
  size -1 -1 136 102
  option dbu
  box Nick:, 6, 66 0 68 97
  text "Arkadaşına + verir.", 12, 70 20 68 97
  button Ekle(+), 4, 82 30 39 11
  button Kaldır(-), 10, 82 46 39 11
  edit "", 1, 70 8 61 10, autohs
  button Tamam, 3, 82 70 39 18, default ok
  list 2, 5 3 57 83, size
  check Sistemi Aktifleştir, 5, 7 89 51 10
}

on 1:dialog:arkadaslist:sclick:5:{
  if ($did(5).state == 1) { .enable #arkadaslist | .echo -a 4Arkadaş Listesi 14Aktif Edildi. }
  else { .disable #arkadaslist | .echo -a 4Arkadaş Listesi 14Deaktif Edildi. }
}
on *:dialog:arkadaslist:*:*:{
  if ($group(#arkadaslist) == on) { did -c arkadaslist 5 } 
  if ($devent == sclick) {
    if ($did == 4) { .did -a arkadaslist 2 $did(arkadaslist,1) | .auser arkadaslist $did(arkadaslist,1) | .did -r arkadaslist 1 } 
    if ($did == 10) { .ruser arkadaslist $did(arkadaslist,2).seltext | .did -d arkadaslist 2 $did(arkadaslist,2).sel } 
  }
  if ($devent == init) {
    if $ulist(*,arkadaslist,0) > 0 { 
      var %i 1 
      while %i <= $ulist(*,arkadaslist,0) { 
        .did -a arkadaslist 2 $ulist(*,arkadaslist,%i) 
        inc %i  
      } 
    } 
  } 
}