on *:dialog:badnick:sclick:19:{ if %bn_tarama { unset %bn_tarama | did -u $dname 19 } | else { set %bn_tarama 1 | did -c $dname 19 } }
on *:OP:#:{ $iif(%bn_tarama && $opnick == $me,tara_ $chan) }
on *:HELP:#:{ $iif(%bn_tarama && $hnick == $me,tara_ $chan) }
on *:dialog:badnick:init:*:{
  if $file(system\badnick.txt) {
    var %x = 1 | while %x <= $lines(system\badnick.txt) {
      didtok $dname 2 32 $read(system\badnick.txt,%x) | inc %x
    }
  }
  $iif(%bn_kanal,didtok $dname 7 44 %bn_kanal)
  $iif(%bn_cinsellik,didtok $dname 12 44 %bn_cinsellik)
  $iif(%bn_oper,did -c $dname 16)
  $iif(%bn_tarama,did -c $dname 19)
  $iif(%bn_sebep,did -a $dname 18 %bn_sebep)
}
on *:dialog:badnick:sclick:4,5:{
  set %bn_list 1
  if $did == 4 { did -a $dname 2 $did(1) | did -r $dname 1 }
  if $did == 5 { 
    if $did(2,0).sel > 1 { var %y = $did(2,0).sel | while %y { did -d $dname 2 $did(2,%y).sel | dec %y } }
    else { did -d $dname 2 $did(2).sel } 
  } 
}
on *:dialog:badnick:sclick:9,10,13,14:{
  if $did == 9 { did -a $dname 7 $iif($left($did(8),1) != $chr(35),$+($chr(35),$did(8)),$did(8)) | did -r $dname 8 }
  if $did == 10 { 
    if $did(7,0).sel > 1 { var %y = $did(7,0).sel | while %y { did -d $dname 7 $did(7,%y).sel | dec %y } }
    else { did -d $dname 7 $did(7).sel } 
  }
  if $did == 13 { did -a $dname 12 $iif($left($did(15),1) != $chr(35),$+($chr(35),$did(15)),$did(15)) | did -r $dname 15 }
  if $did == 14 { 
    if $did(12,0).sel > 1 { var %y = $did(12,0).sel | while %y { did -d $dname 12 $did(12,%y).sel | dec %y } }
    else { did -d $dname 12 $did(7).sel } 
  } 
}
on *:dialog:badnick:sclick:16:{ if %bn_oper { unset %bn_oper | did -u $dname 16 } | else { set %bn_oper 1 | did -c $dname 16 } }
on *:dialog:badnick:close:*:{
  if %bn_list { 
    write -c system\badnick.txt
    var %u = 1 | while %u <= $did(2).lines {
      write system\badnick.txt $did(2,%u) $did(2,$calc(%u + 1)) $did(2,$calc(%u + 2)) $did(2,$calc(%u + 3)) | inc %u 4 
    }
    unset %bn_list 
  }
  unset %bn_kanal | unset %bn_cinsellik
  var %ı = 1 | while %ı <= $did(7).lines { set %bn_kanal $addtok(%bn_kanal,$did(7,%ı),44) | inc %ı }
  var %o = 1 | while %o <= $did(12).lines { set %bn_cinsellik $addtok(%bn_cinsellik,$did(12,%o),44) | inc %o }
  set %bn_sebep $did(18)
}
alias tara_ {
  var %bn_liste = system\badnick.txt
  if !$2 { 
    var %x = 1 | while $read(%bn_liste,%x) {
      var %v2 $v1
      var %y = 1 | while $nick($1,%y) { var %v1 $v1
        if (%v2 iswm %v1) {
          if ($me isop $1) || ($me ishop $1) { 
            mode $1 +b %v2 | kick $1 $nick($1,%y) %bn_sebep
            $iif(%bn_oper && o isincs $usermode,sajoin %v2 $+(0,%bn_cinsellik)) 
          }
          else { 
            .cs akick $1 add %v2 %bn_sebep
            set %bn_akick $addtok(%bn_akick,%v2,44)
            $iif(%bn_oper && o isincs $usermode,sajoin %v2 $+(0,%bn_cinsellik)) 
          } 
        }
        inc %y 
      }
      inc %x 
      if %x > $lines(%bn_liste) && %bn_akick { var %k = $1 | .cs akick $1 enforce
      tokenize 44 %bn_akick | .cs akick %k del $* | unset %bn_akick } 
    } 
  }
  else { 
    var %z = 1 
    while $read(%bn_liste,%z) {
      var %v1 $v1
      if (%v1 iswm $2) {
        if ($me isop $1) || ($me ishop $1) { 
          mode $1 +b %v1 | kick $1 $2 %bn_sebep 
          $iif(%bn_oper && o isincs $usermode,sajoin $2 $+(0,%bn_cinsellik)) 
        }
        else { 
          .cs akick $1 add %v1 %bn_sebep
          .cs akick $1 enforce | .cs akick $1 del %v1
          $iif(%bn_oper && o isincs $usermode,sajoin $2 $+(0,%bn_cinsellik))
        }
      }
      inc %z 
    } 
  }
}
#badnick_tarama on
on *:join:%bn_kanal:{ if $nick == $me { .timer 1 3 tara_ $chan } | else { tara_ $chan $nick } }
#badnick_tarama end
menu channel {
  -
  BadNick Tarama %badnick_tarama {
    if %badnick_tarama == (Açık) { .disable #badnick_tarama | .set %badnick_tarama (Kapalı) }
    else { .enable #badnick_tarama | .set %badnick_tarama (Açık) }
  }
  .BadNick Taraması Yap ( $+ $active $+ ): tara_ $chan
  .BadNick Tarama Ayarları: dialog $iif(!$dialog(badnick),-m badnick,-v) badnick 
  -
}