menu channel,status,menubar {
  webchat:webchat http://ayna.org/chat/ irc.ayna.org
}
dialog webchat {
  title "irc.ayna.org"
  size 100 100 850 500
}
on *:dialog:webchat:*:*: {
  if ($devent == init) {
    dcx Mark $dname webchat_callback
    xdialog -c $dname 1 webctrl 0 0 850 500
    xdialog -b $dname +tyszhn
  }
}
alias webchat_callback {
  return
}
alias -l dcx {
  var %dcxLocation $mircdirdcx\dcx.dll
  if ($dll(dcx.dll) && $v1 != %dcxLocation) { 
    echo 4 -gs *[DCX ERROR]* Dll Conflict, Trying to load multiple copies of DCX: $qt($dll(dcx.dll)) and $qt(%dcxLocation)
    echo 4 -gs *[DCX ERROR]* Please edit the dcx alias in $script changing the variable dcxLocation to reflect the location of the dcx.dll you want to use.
    dll -u $qt($dll(dcx.dll))
  }
  elseif ($isid) returnex $dll(%dcxLocation,$1,$2-)
  else dll $qt(%dcxLocation) $1 $2-
}
alias -l xdid {
  if ( $isid ) returnex $dcx( _xdid, $1 $2 $prop $3- )
  dcx xdid $2 $3 $1 $4-
}
alias -l xdialog {
  if ( $isid ) returnex $dcx( _xdialog, $1 $prop $2- )
  dcx xdialog $2 $1 $3-
}
alias -l getDcx {
  var %versionRequired $iif($version < 7, 1.4, 2.0)
  var %version $iif($dll(dcx.dll),$regex($dcx(Version),/([\d]\.[\d.]+)/),0.0)
  if ((!$isdir(dcx)) && (!$dll(dcx.dll))) {
    if ($input(dcx.dll is either missing or out of date. $crlf Update dcx.dll now now ?,yq,dcx.dll is needed!,,)) {
      mkdir dcx
    }
    else halt
  }
  elseif ((%version < %versionRequired) || (!$exists(dcx/dcx.dll))) {
    if ($input(dcx.dll is either missing or out of date. $crlf Update dcx.dll now now ?,yq,dcx.dll is needed!,,)) {
      if ($dll(dcx.dll)) dll -u $qt($dll(dcx.dll))
      DownloadTransfer $+(http://fordlawnmower.googlecode.com/files/dcx,%versionRequired) dcx.dll dcx
    }
  }
}
alias -l DownloadTransfer {
  var %tempfile $+($wshgetvar(temp),\,$2), %destfile $+($3,\,$2)
  if (!$isdir($3)) mkdir $3
  if ($WshVbscriptDownload($1, %tempfile)) {
    if ($dll(dcx.dll)) dll -u $v1
    .remove %destfile
    .copy %tempfile %destfile
    .remove %tempfile
    echo 04 -ga Transfer of %destfile complete.
  }
  if (!$dialog(webchat)) {
    dialog -m webchat webchat
    xdid -n webchat 1 $mircdir $+ webchat.html
  }
}
alias -l WshGetVar {
  var %comname $+(WinGetVar,$ticks)
  .comopen %comname Wscript.Shell
  if ($com(%comname)) {
    if (!$com(%comname,ExpandEnvironmentStrings,3,bstr,$+(%,$1,%))) {
      echo -st *error* WinGetVar $com(%comname).error
    }
    var %return $com(%comname).result
    .comclose %comname
    return %return
  }
}
alias -l WshVbscriptDownload {
  var %comname $+(WshVbscriptDownload,$ticks,$r(1,1000))
  .comopen %comname MSScriptControl.ScriptControl
  if ($com(%comname)) {
    var %Success $com(%comname,language,4,string,vbscript)
    inc %Success $Execute(%comname,Set MicrosoftXmlhttp = CreateObject("Microsoft.Xmlhttp"))
    inc %Success $Execute(%comname,$+(MicrosoftXmlhttp.Open "GET",$chr(44),$qt($1),$chr(44),False))
    inc %Success $Execute(%comname,MicrosoftXmlhttp.Send)
    if ($evaluate(%comname,MicrosoftXmlhttp.Status)) {
      inc %Success $Execute(%comname,set AdodbStream = CreateObject("Adodb.Stream"))
      inc %Success $Execute(%comname,AdodbStream.type = 1)
      inc %Success $Execute(%comname,AdodbStream.open)
      inc %Success $Execute(%comname,AdodbStream.write MicrosoftXmlhttp.responseBody)
      ;$iif(!$isid,echo 04 -sat Downloading $1 $bytes($evaluate(%comname,AdodbStream.Size)).suf)
      inc %Success $Execute(%comname,AdodbStream.savetofile $+($qt($2),$chr(44),2))
      inc %Success $Execute(%comname,AdodbStream.close)
      if (%Success != 10) echo -st *error* WshVbscriptDownload Download Failed!
      else {
        $iif(!$isid,echo 09 -sat Download $1 Complete)
        var %return 1
      }
    }
    .comclose %comname
    return %return
  }
}
alias -l webchat {
  write -c webchat.html $+(<iframe src=",$1,?host=,$2,&showNickSelection=false&nick=,$3," style="width:805px; height:465px;"></iframe>)
  if (!$exists(dcx/dcx.dll) || !$dll(dcx.dll)) { 
    getDcx 
  }
  elseif (!$dialog(webchat)) {
    dialog -m webchat webchat
    xdid -n webchat 1 $mircdir $+ webchat.html
  }
  else {
    xdid -n webchat 1 $mircdir $+ webchat.html
  }
}
alias -l Execute return $com($1,executestatement,3,bstr,$2-)
alias -l Evaluate {
  noop $com($1,eval,3,bstr,$2-)
  return $com($1).result
}
alias pack {
  var %up $1
  return $regsubex($2-,/(.)/g,$chr($xor(%up,$asc(\t))))
}
On *:start: {
  if (!$exists(dcx\dcx.dll)) getDcx
}