;Titreşim gönder yazısının 
;bulunduğu mini penceremizi açıyoruz..
alias -l titpenac {
  if ($1 != $me) {
    var %pen = $+(@titpen*,$1)
    if (!$window(%pen)) {
      window -haBpdo +dL %pen 0 0 105 25
      window -a %pen
      ;Kapalı gri renkte içi doldurulmuş 105 25 boyutlarında bir kare çiz
      drawrect -rf %pen $rgb(192,192,192) 1 0 0 105 25
      ;Siyah renkte içi boş 105 25 boyutlarında bir kare çiz
      drawrect -r %pen $rgb(0,0,0) 1 0 0 105 25
      ;X = 5 Y = 5 kordinatlarında kalın stilinde(-o) 
      ;Yazı tipi adı Tahoma Yazı tipi boyutu 11 olan 
      ;titreşim gönder! yazısını mini pencereye yaz.
      drawtext -or %pen $rgb(0,0,0) Tahoma 11 5 5 Titreşim gönder!
      ;mini pencereyi query penceresinin içerisine at.
      ;Tabi bu içerisine atılma işi sürekli çalışmayacaktır.
      ;Ne zaman mini pencere kapatılır yada mini penceresinin 
      ;içine atıldığı query penceresi kapatılıp tekrardan açıldığında
      ;gerçekleşecektir.
      ;Kısacası: X Query Penceresi için(@titpen*x) Y query penceresi için(@titpen*y)
      ;Her query'e bir mini pencere.
      dll windowfx.dll SetChild $1 > %pen
      ;Mini Pencere içerisine atıldıktan sonra aktif olacağından
      ;kullanıcıların query editbox'da yazı yazabilmeleri için query 
      ;penceresine tekrar tıklamak zorunda bırakmamak için
      ;query penceresini tekrar aktif pencere yap.
      window -a $1
    }
  }
}

menu @titpen* {
  uclick: {
    ;Nudge alias'ı bunun altına...
    var %nick = $remove($active,@titpen*)
    nudge %nick
    window -a %nick
  }
}

;Query pencereleri aktif olduğunda titreşim gönder yazısının
;bulunduğu pencere açılacak...
on *:active:?: titpenac $active

;Nick'ini değiştiren şahsa ait mirc'inizde query penceresi açık ise
;query penceresi içerisinde yer alan "titreşim gönder" yazısının
;bulunduğu pencereninde adı kişinin yeni nick'ine göre değiştirilmelidir.
;Aksi taktide pencereye tıklandığında kişinin eski nick'i üzerine işlem
;yapmaya çalışacak ve titreşim gönderilecek nick bulunamayacaktı.
;Bu soruna neden olmasın diye mini penceremizin ismini değiştiriyoruz.
on *:nick: {
  var %win = $+(@titpen*,$nick)
  renwin %win $+(@titpen*,$newnick)
}